Imports System
Imports System.Collections.Generic
Imports System.ComponentModel
Imports System.Drawing
Imports System.Data
Imports System.Text
Imports System.Windows.Forms

' ||*****************************************************************************************************************************||
'   Title  : DragDropGrid
'   Author : Thomas B. Holland
'   Date   : 01/03/08
'   
'   The base code for this control was taken from the article "How Do I Perform A Drag And Drop Reorder Of Rows?" on
'   WindowsClient.net.  The author is not stated in the article.
'
'   The DragDropGrid enables Drag And Drop functionality between 2 DataGridViews without having to write any code.  The new control
'   exposes two new properties that will appear under "Misc" section in the properties window.  They are AllowDrag and AllowReorder.
'   
'   The AllowDrag property sets the ability to drag and item from the control.  If you do not set this property, attempting to drag
'   will simply highlight rows as you drag over them.
'
'   The AllowReorder property lets the control know that it is ok for items to be reordered within the same control.
'
'   It is possible to drag between two or more DragDropGrids and also reorder within the same DragDropGrid.
'
'   Only 1 item can be moved at a time.  Moving of a selection of multiple items is not supported.
' ||*******************************************************************************************************************************||

Namespace Controls
    Public Class DragDropGrid
        Inherits DataGridView

        'Constructor
        Public Sub New()
            dt = Nothing
        End Sub

        Private dragBoxFromMouseDown As Rectangle
        Private isDragging As Boolean = False
        Private ds As New DataSet
        Private bs As New BindingSource
        Public dt As New DataTable
        Public rowIndexFromMouseDown As Int32 = 0
        Public rowIndexOfItemUnderMouseToDrop As Int32 = 0

#Region "CustomProperties"

        Private _AllowReorder As Boolean = False
        Private _AllowDrag As Boolean = False
        Private _DragType As enumDragType

        Public Property AllowDrag() As Boolean

            Get
                Return _AllowDrag
            End Get
            Set(ByVal value As Boolean)
                _AllowDrag = value
            End Set

        End Property

        Public Property AllowReorder() As Boolean

            Get
                Return _AllowReorder
            End Get
            Set(ByVal value As Boolean)
                _AllowReorder = value
            End Set

        End Property

        Public Enum enumDragType
            Move
            Copy
        End Enum

        Public Property DragType() As enumDragType
            Get
                Return _DragType
            End Get
            Set(ByVal value As enumDragType)
                _DragType = value
            End Set
        End Property


#End Region

#Region "EventOverrides"

        Protected Overrides Sub OnMouseDown(ByVal e As System.Windows.Forms.MouseEventArgs)

            If AllowDrag Then

                'Get the index of the item the mouse is below.
                rowIndexFromMouseDown = Me.HitTest(e.X, e.Y).RowIndex

                If (Not rowIndexFromMouseDown = -1) Then
                    ' Remember the point where the mouse down occurred.
                    ' The DragSize indicates the size that the mouse can move
                    ' before a drag event should be started.               
                    Dim dragSize As Size = SystemInformation.DragSize
                    ' Create a rectangle using the DragSize, with the mouse position being
                    ' at the center of the rectangle.
                    dragBoxFromMouseDown = New Rectangle(New Point(CType(e.X - (dragSize.Width / 2), Int32), _
                    CType(e.Y - (dragSize.Height / 2), Int32)), dragSize)
                Else
                    ' Reset the rectangle if the mouse is not over an item in the ListBox.
                    dragBoxFromMouseDown = Rectangle.Empty
                End If
            End If
            MyBase.OnMouseDown(e)
        End Sub

        Protected Overrides Sub OnMouseMove(ByVal e As System.Windows.Forms.MouseEventArgs)

            If (e.Button And MouseButtons.Left) = MouseButtons.Left Then

                ' If the mouse moves outside the rectangle, start the drag.
                If Not dragBoxFromMouseDown = Rectangle.Empty And _
                    Not dragBoxFromMouseDown.Contains(e.X, e.Y) Then

                    ' Proceed with the drag and drop, passing in the list item.                   
                    Dim dropEffect As DragDropEffects = Me.DoDragDrop( _
                    Me.Rows(Me.rowIndexFromMouseDown), _
                    DragDropEffects.Move)
                    Me.isDragging = True
                End If

            End If

            MyBase.OnMouseMove(e)

        End Sub

        Protected Overrides Sub OnDataBindingComplete(ByVal e As System.Windows.Forms.DataGridViewBindingCompleteEventArgs)

            Try
                If Me.DataSource.GetType Is GetType(BindingSource) Then
                    bs = CType(Me.DataSource, BindingSource)
                    ds = CType(Me.bs.DataSource, DataSet)
                    dt = ds.Tables(0)
                ElseIf Me.DataSource.GetType Is GetType(DataSet) Then
                    ds = CType(Me.DataSource, DataSet)
                    dt = ds.Tables(0)
                Else
                    dt = Nothing
                End If

            Catch ex As Exception

            End Try

            MyBase.OnDataBindingComplete(e)

        End Sub

        Protected Overrides Sub OnDragDrop(ByVal e As System.Windows.Forms.DragEventArgs)

            ' The mouse locations are relative to the screen, so they must be
            ' converted to client coordinates.
            Dim clientPoint As Point = Me.PointToClient(New Point(e.X, e.Y))

            ' Get the row index of the item the mouse is below.
            Me.rowIndexOfItemUnderMouseToDrop = _
            Me.HitTest(clientPoint.X, clientPoint.Y).RowIndex

            ' If the drag operation was a move then remove and insert the row.
            If e.Effect = DragDropEffects.Move Then
                Try

                    Dim rowToMove As DataGridViewRow = CType(e.Data.GetData(GetType(DataGridViewRow)), DataGridViewRow)
                    Dim dragInitiator As DragDropGrid = CType(rowToMove.DataGridView, DragDropGrid)
                    Me.rowIndexFromMouseDown = dragInitiator.rowIndexFromMouseDown

                    'If the source grid is bound, then remove the items from the underlying dataset and rebind
                    If dt Is Nothing Then

                        'If its a move, then delete the source item
                        If dragInitiator.DragType = enumDragType.Move Then
                            dragInitiator.Rows.RemoveAt(rowIndexFromMouseDown)
                        Else
                            Dim rowClone As DataGridViewRow
                            rowClone = CType(rowToMove.Clone(), DataGridViewRow)
                            For i As Integer = 0 To rowClone.Cells.Count - 1
                                rowClone.Cells(i).Value = rowToMove.Cells(i).Value
                            Next
                            rowToMove = rowClone
                        End If

                        ' If we are attempting to drop this new row on the datagrid in a spot where the mouse is not over some rows, then we need
                        ' to add it instead of trying to insert it at an index that is out of range.
                        If Me.rowIndexOfItemUnderMouseToDrop > -1 Then
                            Me.Rows.Insert(rowIndexOfItemUnderMouseToDrop, rowToMove)
                        Else : Me.Rows.Add(rowToMove)
                        End If

                        'This control is data bound so modify the underlying data tables
                    Else

                        'get the row data from row before removing and add to new row
                        Dim rowArray As Object() = dragInitiator.dt.Rows(rowIndexFromMouseDown).ItemArray
                        Dim row As DataRow = Me.dt.NewRow()
                        row.ItemArray = rowArray

                        'remove old row and insert new row
                        If Me.rowIndexOfItemUnderMouseToDrop > -1 Then
                            Me.dt.Rows.InsertAt(row, rowIndexOfItemUnderMouseToDrop)
                        Else : dt.Rows.Add(row)
                        End If

                        'If its a move, then delete the source item
                        If dragInitiator.DragType = enumDragType.Move Then dragInitiator.dt.Rows.RemoveAt(rowIndexFromMouseDown)

                    End If

                Catch ex As Exception

                    Throw New Exception(ex.Message)

                End Try


            End If

            Me.isDragging = False
            MyBase.OnDragDrop(e)

        End Sub

        Protected Overrides Sub OnDragOver(ByVal e As System.Windows.Forms.DragEventArgs)

            Dim rowToMove As DataGridViewRow = CType(e.Data.GetData(GetType(DataGridViewRow)), DataGridViewRow)
            Dim gridInitiator As DragDropGrid = CType(rowToMove.DataGridView, DragDropGrid)


            Dim clientPoint As Point = Me.PointToClient(New Point(e.X, e.Y))

            ' Get the row index of the item the mouse is below.
            Me.rowIndexOfItemUnderMouseToDrop = _
            Me.HitTest(clientPoint.X, clientPoint.Y).RowIndex

            Dim row As DataGridViewRow

            ' Reset The Selected property to false so that any row that was selected
            ' and is no longer under the mouse becomes deselected
            For Each row In Me.Rows
                row.Selected = False
            Next

            ' Now set the row underneath the mouse to selected.  This is strictly for asthetic purposes
            If (Me.rowIndexOfItemUnderMouseToDrop > -1) Then Me.Rows(Me.rowIndexOfItemUnderMouseToDrop).Selected = True

            ' If the AllowReorder property is set to True, then allow the drag
            ' If the AllowReorder property is set to False, and the control where the drag began is this, deny the drag
            ' If the AllowReorder property is set to False, and the control where the drag began is NOT this, then allow the drag
            If (AllowReorder) Then
                e.Effect = DragDropEffects.Move
            ElseIf gridInitiator Is Me Then
                e.Effect = DragDropEffects.None
            Else
                e.Effect = DragDropEffects.Move
            End If

            MyBase.OnDragOver(e)

        End Sub

#End Region

    End Class
End Namespace